!-----------------------------------------------------------------------------------
Esto es un ejemplo de respuesta de examen a un problema de modelizar, concretamente,
al ejemplo de la página 210 de los apuntes.

No sólo hay que escribir el modelo en LINGO, sino dejar claro qué es cada variable,
qué es la función objetivo y qué significa cada restricción (dejando claro qué es el
miembro izquierdo y qué es el miembro derecho).

Al final debéis indicar la solución óptima con palabras, no dando meramente el valor
de las variables.

En la corrección se valorará que las explicaciones estén detalladas hasta el nivel
que muestra este ejemplo (no es necesario extenderse más). Por ejemplo, tendrá menos
nota quien diga: T = ternera,  M = mixta, y mucha menos quien no diga nada.

Observad que para escribir comentarios en LINGO basta empezar con una exclamación y
terminar con punto y coma. En los comentarios podéis poner acentos, eñes, etc.
------------------------------------------------------------------------------------;


!EJEMPLO:  Producir 500 hamburguesas de ternera y 200 mixtas. Contratar 50 trabajadores para la planta 1 y 30 para la planta 2

VARIABLES:

 T  = Hamburguesas de ternera que hay que producir
 M  = Hamburguesas mixtas que hay que producir
 P1 = Trabajadores que conviene contratar para la planta 1
 P2 = Trabajadores que conviene contratar para la planta 2;

[Beneficio] Max = (2+10000/(M+T+1))*T+(1+10000/(M+T+1))*M-4*0.2*T-2*0.1*M-4*0.15*M-40*P1-35*P2;

!kg de ternera necesarios < kg disponibles;
[Ternera]0.2*T+0.15*M < 3000;

!kg de cerdo necesarios < kg disponibles;
[Cerdo]0.1*M < 3100;

!Hamburguesas de ternera que podemos producir > hamburguesas producidas;
[TT]140*P1+160*P2 > T;

!Hamburguesas mixtas que podemos producir > hamburguesas producidas;
[TM] 270*P1+750*P2 > M;

!Hamburguesas mixtas producidas > tres veces el número de hamburguesas de ternera;
[Proporcion] M > 3*T;

!Trabajadores contratados en la planta 2 < capacidad de la planta;
[Capacidad]P2<15;

!Las hamburguesas producidas y los trabajadores contratados son variables enteras;
@GIN(T);@GIN(M);@GIN(P1);@GIN(P2);

!La solución óptima es producir 4615 hamburguesas de ternera y 13846 hamburguesas mixtas
 y contratar 16 trabajadores para la planta 1 y 15 para la planta 2;