model {
 	# Likelihood
	for (i in 1:Nareas) {
		for (k in 1:Ndiseases) {
			Y[i, k] ~ dpois(mu[i, k])
			log(mu[i, k]) <- log(E[i, k]) + alpha[k] + S[i,k]
  			RR[i,k] <- exp(alpha[k] + S[i,k])
		}
  	}

	for (i in 1:Nareas){
		for(k in 1:Ndiseases){
			S[i,k]<-inprod(tDelta[1:k,i],CholDis[k,1:k])
		}
	}

	for(j in 1:Ndiseases){tDelta[j,1:Nareas]~car.l1(adj[], weights[], num[],1)}
		  	
	#Between-diseases structure
	#Cholesky triangle of a general correlation matrix
	#diagonal
	CholDis[1,1]<-sigma[1]
	for(j in 2:Ndiseases){
		diag[j]<-pow(sigma[j],2)-inprod(CholDis[j,1:(j-1)],CholDis[j,1:(j-1)])
		CholDis[j,j]<-sqrt(abs(diag[j]))
	}

	#Lower triangle
	#First column
	for(i in 2:Ndiseases){CholDis[i,1]<-sigma[i]*roDis[i,1]}
	#Rest of columns 
	for(j in 2:(Ndiseases-1)){
		for(i in (j+1):Ndiseases){
			CholDis[i,j]<-(roDis[i,j]*sigma[i]*sigma[j]-inprod(CholDis[i,1:(j-1)],CholDis[j,1:(j-1)]))/CholDis[j,j]
		}
	}

	for(j in 1:Ndiseases){roDis[1,j]<-0}
	for(i in 2:Ndiseases){
		for(j in 1:(i-1)){roDis[i,j]~dunif(-1,1)}
		for(j in i:Ndiseases){roDis[i,j]<-0}
	}

	#Condition of being positive defined the covariance matrix
	uno<-1 
	uno~dbern(condition)
	condition<-step(sum(subcondition[2:Ndiseases])-(Ndiseases-1))
	for(j in 2:Ndiseases){subcondition[j]<-step(diag[j])}

	# Other priors
	for (k in 1:Ndiseases) {
		alpha[k] ~ dflat()
		sigma[k] ~ dunif(0,10)
	}
}