model{
	for(k in 1:(nGroups[4])){#Sex
		for(j in 1:(nGroups[3])){#Disease
			for (p in 1:(nGroups[2])){#Period
				for(i in 1:(nGroups[1])){#Municipality
					Obs[i,p,j,k]~dpois(mu[i,p,j,k])
					log(mu[i,p,j,k])<-log(Expect[i,p,j,k])+alpha[p,j,k]+S1234[i,p,j,k]
					RR[i,p,j,k]<-exp(alpha[p,j,k]+S1234[i,p,j,k])

					S12[i,p,j,k]<-inprod2(tS1[k,j,,i],structure2[,p])

					for (kk in 1:(nGroups[4])){
						suma[i,p,j,k,kk]<-inprod2(S12[i,p,,kk],structure34[(nGroups[3]*(k-1)+j),((kk-1)*nGroups[3]+1):((kk-1)*nGroups[3]+nGroups[3])])
					}
					S1234[i,p,j,k]<-sum(suma[i,p,j,k,1:(nGroups[3])])

				}#Fin i
				alpha[p,j,k]~dflat()
				tS1[k,j,p,1:(nGroups[1])]~car.proper(ceros[],C[],adj[],num[],M[],1,gamma)
			}#Fin p
		}#Fin j
	}#Fin k

	for(l in 1:(nGroups[1])){ceros[l]<-0}
	gamma.inf<-min.bound(C[],adj[],num[],M[])
	gamma.sup<-max.bound(C[],adj[],num[],M[])
	gamma~dunif(gamma.inf,gamma.sup)
	
	#Dimension 2: Period
	#Definition structure2 ->period (Cholesky Matrix for autoregressive process)	
	#Traspuesta de la triangular inferior: triangular superior
	for (pc in 1:(nGroups[2])){
		#First Row
		structure2[1,pc]<-pow(ro,pc-1)*pow((1-ro*ro),-0.5)
		#Rest of columns
		for (pr in 2:(nGroups[2])){
			structure2[pr,pc]<-step(pc-pr)*pow(ro,pc-pr)
		}
	}
	ro~dunif(-1,1)

	#Dimensions 3 y 4 (Disease and Sex): 
	for (i in 1:(nGroups[3]*nGroups[4])){
		for (j in 1:(nGroups[3]*nGroups[4])){
			structure34[i,j] ~ dnorm(0,prec) 
		}
	}

	prec<-pow(sdstruct,-2)
	sdstruct~dunif(0,100)
}